Запись онлайн радио на роутер: MikroTik RouterOS Script

Продолжаю мучить свой запасной роутер. Ранее он научился присылать мне смс. Потом научился мониторить свой мобильный интернет. Теперь он умеет записывать музыку с онлайн радиостанций. Чтоб другие роутеры в сети над ним не смеялись, зато что он слушает какую то попсу, записывать будем BassDrive и JungleTrain.

Для этого нужна только USB флешка (fat32), ну и сам роутер. Скрипт свежий, проверялся на 7.22.2

Скриптов будет два, первый просто пишет поток в mp3 файл, назовём его bassDriveRecorder. В именах скриптов я использую название станций, чтоб удобно было писать сразу несколько потоков. Здесь у нас проверка и удаление "temp" файла перед записью и сама запись.

:global bassDriveStartFile 
:if ([:len [/file find name=$bassDriveStartFile]] > 0) do={
    /file remove [find name=$bassDriveStartFile]
}
/tool fetch url="https://chi2.bassdrive.net/stream" dst-path=$bassDriveStartFile

# https://chi2.bassdrive.net/stream
# https://bassdrive.radioca.st/stream
# https://au.bassdrive.co/stream
# https://ice.bassdrive.net/stream
# https://ice.bassdrive.net/stream32
# https://ice.bassdrive.net/stream56

Этот скрипт пишет поток в mp3 файл, с (стартовым) именем. Имя файла в переменную bassDriveStartFile задаётся во втором скрипте.

В моём случае стартовое имя для файла при начале записи всегда usb1/bassDrive/bassDriveLive.mp3

При таком запросе к потоку, fetch будет писать файл бесконечно. Если запись прервать или остановить скрипт, файл будет удалён как не валидный. По этому мы после начала записи, на второй итерации второго скрипта, переименуем его. Тогда при остановке пишущего скрипта, файл останется. Так как fetch будет пытаться удалить usb1/bassDrive/bassDriveLive.mp3 которого уже нет.

Второй скрипт менеджер, назовём его bassDriveManager

Для него (сами) создаём задание в планировщике, и запускаем его раз в минуту.

:global bassDriveCurrentShow
:global bassDriveStartFile
:local scriptRecorder "bassDriveRecorder"
:local diskSlot "usb1"
:local folder ($diskSlot . "/bassDrive/")

:local freeSpace (([/disk print as-value where slot=$diskSlot]->0)->"free")

:if ([:len "$freeSpace"] = 0) do={
    :log warning ("disk unavailable: " . $diskSlot . " script " . $scriptRecorder . " stopped")
    /system script job remove [find script=$scriptRecorder]
    :quit
}

# проверить свободное место, минимально допустимое свободное место (100 MB)
:local minFreeBytes 104857600
:if ($freeSpace < $minFreeBytes) do={
    :log warning ("low disk space on " . $diskSlot . "script " . $scriptRecorder . " stopped")
    /system script job remove [find script=$scriptRecorder]
    :quit
}


# начало блока отвечающего за название шоу или песни

:local result
:do {
    :set result [/tool fetch url="https://bassdrive.com/now-playing.php" output=user as-value]
} on-error={
    :log warning ("get now-playing show failed " . "script " . $scriptRecorder . " stopped") 
    /system script job remove [find script=$scriptRecorder]
    :quit
}

:local html ($result->"data")

:local spanPos [:find $html "<span"]
:local newShow ""

:if ([:len "$spanPos"] > 0) do={
    :set newShow [:pick $html 0 $spanPos]
} else={
    :log warning "BassDrive parser error: <span not found"
    :set newShow "Unknown BassDrive Show"
}


# конец блока отвечающего за название шоу или песни


:local sanitizeShow
:set sanitizeShow do={
    :local input $1
    :local allowed "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789_- "
    :local result ""
    :for i from=0 to=([:len $input] - 1) do={
        :local c [:pick $input $i ($i + 1)]
        :if ($allowed ~ $c) do={
            :set result ($result . $c)
        }
    }

    :while (([:len $result] > 0) && ([:pick $result ([:len $result] - 1)] = " ")) do={
        :set result [:pick $result 0 ([:len $result] - 1)]
    }
    :return $result
}

:local cleanName [$sanitizeShow $newShow]
:log info ("BassDrive current show: " . $newShow . "clean: " . $cleanName)
:local newFileName ($folder . $cleanName . ".mp3")
:local finalName $newFileName
:local counter 1
:while ([:len [/file find name=$finalName]] > 0) do={
    :set finalName ($folder . $cleanName . "_" . $counter . ".mp3")
    :set counter ($counter + 1)
    }

:if ([:len [/system script job find script=$scriptRecorder]] = 0) do={
    :set bassDriveStartFile ($folder . "bassDriveLive.mp3")
    :set bassDriveCurrentShow $newShow
    /system script run $scriptRecorder

} else={
   :if ($bassDriveCurrentShow != $newShow) do={
        /system script job remove [find script=$scriptRecorder]
        :log info "bassDrive new show started"
        :set bassDriveCurrentShow $newShow
        /system script run $scriptRecorder
    } else={
       :if ([:len [/file find name=$bassDriveStartFile]] > 0) do={
        /file set name=$finalName $bassDriveStartFile     
       }
    }
}

• :global bassDriveCurrentShow - переменная, хранит название текущей песни или шоу

• :global bassDriveStartFile - переменная, хранит стартовый путь в файлу при записи

• :local scriptRecorder "bassDriveRecorder" - название первого скрипта пишущего файлы

• :local diskSlot "usb1" - слот USB диска

• :local folder ($diskSlot . "/bassDrive/") - папка для удобства. можно "/" писать в корень.

Скрипт проверяет наличие флешки и свободного места (> 100мб) на ней. Если диска или места нет, ничего не делаем. Далее идёт блок отвечающий за получение текущей песни или шоу, по большому счёту это почти единственное место которое вам надо будет изменить под вашу радиостанцию. Это и ссылку на поток в первом скрипте. И всё, остальное менять не надо.

Для BassDrive мы делаем запрос к https://bassdrive.com/now-playing.php и парсим ответ, всё что до тега <span>. Дальше чистим название шоу от мусорных символов которые нельзя использовать в названии файлов. Наш конечный файл будет иметь имя: название шоу или песни и формат mp3. Если при запросе названия песни была ошибка, например нет интернета, ничего не делаем. При каждом ничего не деланьи я останавливаю пишущий скрипт, чтоб он зря не висел в системе.

Ну и дальше самое главное, когда у нас есть название песни или файла, мы проверяем работает ли пишущий скрипт. Если не пишет, то сохраняем название песни в переменную, инициализируем имя стартового файла и начинаем запись. При следующем запуске скрипта менеджера (через минуту) имя файла меняем на usb1/bassDrive/название_песни.mp3 чтоб файл не пропал при остановке пишущего скрипта.

Если запись уже идёт, проверяем, отличаются ли названия сохранённой песни с только что полученным. Если разные, сохраняем новое название, останавливаем запись, и сразу её запускаем. Если названия песни одинаковые, проверяем пишется ли она в стартовое имя, если да то переименовываем файл со стартового названия в название с указанием песни usb1/bassDrive/название_песни.mp3.

И всё. Скрипт пишет поток, разбивая его при смене названия песни, переживает перезагрузки, дисконекты и выдёргивание флешки. При остановках записи, в логах будет появляться ошибка

script error: interrupted Это просто сообщение о том что скрипт остановился не сам, а его остановили извне. Чтоб остановить запись, остановите планировщик и остановите скрипт(ы), любой из двух, в вкладке Scripts/Jobs.

Аналогично для другой станции, скрипты под спойлером.

А что слушает ваш роутер?

BassDrive и JungleTrain

Скрытый текст

# первый скрипт рекордер

:global jungleTrainStartFile 
:if ([:len [/file find name=$jungleTrainStartFile]] > 0) do={
    /file remove [find name=$jungleTrainStartFile]
}
/tool fetch url="http://stream1.jungletrain.net:8000/" dst-path=$jungleTrainStartFile

# http://stream1.jungletrain.net:8000/
# http://stream3.jungletrain.net:8000/
# http://stream5.jungletrain.net:8000/   https://chat.jungletrain.net/streamtest


# второй скрипт менеджер

:global jungleTrainCurrentShow
:global jungleTrainStartFile
:local scriptRecorder "jungleTrainRecorder"
:local diskSlot "usb1"
:local folder ($diskSlot . "/jungleTrain/")

:local freeSpace (([/disk print as-value where slot=$diskSlot]->0)->"free")

:if ([:len "$freeSpace"] = 0) do={
    :log warning ("disk unavailable: " . $diskSlot . " script " . $scriptRecorder . " stopped")
    /system script job remove [find script=$scriptRecorder]
    :quit
}

# проверить свободное место, минимально допустимое свободное место (100 MB)
:local minFreeBytes 104857600
:if ($freeSpace < $minFreeBytes) do={
    :log warning ("low disk space on " . $diskSlot . "script " . $scriptRecorder . " stopped" . $freeSpace)
    /system script job remove [find script=$scriptRecorder]
    :quit
}

:local result
:do {
    :set result [/tool fetch url="https://jungletrain.net/static/stats.json" output=user as-value]
} on-error={
    :log warning ("get now-playing show failed script " . $scriptRecorder . " stopped")
    /system script job remove [find script=$scriptRecorder]
    :quit
}

# JSON строка
:local json ($result->"data")

# найти начало значения nowplaying
:local startPos [:find $json "\"nowplaying\": \""]

:local newShow ""

# если нашли поле
:if ([:len "$startPos"] > 0) do={
    # сместиться после "nowplaying": "
    :set startPos ($startPos + 15)
    # найти закрывающую кавычку
    :local endPos [:find $json "\"" $startPos]
    # вырезать название
    :set newShow [:pick $json $startPos $endPos]
    :log warning ("jungleTrain now play " . $newShow)
} else={
    :log warning "jungleTrain parser error: nowplaying not found"
    :set newShow "Unknown JungleTrain Show"
}

:local sanitizeShow
:set sanitizeShow do={
    :local input $1
    :local allowed "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789_- "
    :local result ""
    :for i from=0 to=([:len $input] - 1) do={
        :local c [:pick $input $i ($i + 1)]
        :if ($allowed ~ $c) do={
            :set result ($result . $c)
        }
    }

    :while (([:len $result] > 0) && ([:pick $result ([:len $result] - 1)] = " ")) do={
        :set result [:pick $result 0 ([:len $result] - 1)]
    }
    :return $result
}

:local cleanName [$sanitizeShow $newShow]
:log info ("jungleTrain current show: " . $newShow . "clean: " . $cleanName)
:local newFileName ($folder . $cleanName . ".mp3")
:local finalName $newFileName
:local counter 1
:while ([:len [/file find name=$finalName]] > 0) do={
    :set finalName ($folder . $cleanName . "_" . $counter . ".mp3")
    :set counter ($counter + 1)
    }

:if ([:len [/system script job find script=$scriptRecorder]] = 0) do={
    :set jungleTrainStartFile ($folder . "jungleTrainLive.mp3")
    :set jungleTrainCurrentShow $newShow
    /system script run $scriptRecorder

} else={
   :if ($jungleTrainCurrentShow != $newShow) do={
        /system script job remove [find script=$scriptRecorder]
        :log info "jungleTrain new show started"
        :set jungleTrainCurrentShow $newShow
        /system script run $scriptRecorder
    } else={
       :if ([:len [/file find name=$jungleTrainStartFile]] > 0) do={
        /file set name=$finalName $jungleTrainStartFile     
       }
    }
}