Когда доступ к роутеру есть сразу у нескольких админов, рано или поздно включается режим «коллективной безответственности»: кто‑то поправил правило, ничего не сказал, а разбираться приходится всем. Рассказываю, как настроить на MikroTik простую автоматику, которая сама отследит правки в конфиге и сразу пришлет уведомление с актуальным бэкапом.

Я администрирую сеть одного из филиалов в распределенной инфраструктуре. Доступ к локальному роутеру MikroTik есть не только у меня, но и у коллег из других офисов. Когда кто‑то вносит правки в конфигурацию без предупреждения, разбираться с последствиями на месте приходится именно мне.

Последствия таких правок могут быть разными — всё зависит от ситуации и квалификации конкретного специалиста. Например, однажды коллега сделал «новогодний сюрприз» и переписал правила файрвола по‑своему прямо на праздниках. Пока всё обходилось без серьезных аварий, но если возникнут проблемы и руководство спросит о причинах, мне нужен четкий лог: кто именно, в какой момент и что поменял в настройках. Чтобы не искать концы вслепую, я решил автоматизировать фиксацию любых изменений.

Скрипт написан и проверен на RouterOS v6 (ветка 6.49). Встроенный инструмент /system history в этой версии фиксирует только сам факт изменения и логин администратора, но не показывает подробностей о том, какие именно параметры поменялись. Чтобы видеть полную картину и иметь актуальный слепок настроек сразу после правки, пришлось сделать свой механизм на базе скрипта и стандартного планировщика.

Подготовка к запуску

Вся связка работает только на штатных инструментах RouterOS. Перед тем как добавлять скрипт, проверьте три вещи:

  • У каждого админа должен быть свой логин в меню /user. Если все сидят под общим admin, смысла в логах не будет — вы всё равно не поймете, кто именно вносил правки.

  • Настройте отправку почты в меню /tool e‑mail (укажите адрес SMTP‑сервера, порт, логин и пароль). Для безопасности лучше завести для роутера отдельный технический ящик — например, на Gmail с паролем приложений, а бэкапы слать на независимую корпоративную почту. Даже если злоумышленник получит доступ к роутеру, он не сможет удалить уже ушедшие письма.

  • Выдайте права для скрипта. При создании скрипта отметьте политики (Policies): ftp, read, write, policy и test.

Реализация и код скрипта

Поскольку в RouterOS v6 нет встроенного механизма триггеров на события лога, я написал «скрипт‑ищейку». Он регулярно проверяет буфер логов и, если видит в нем ключевые слова added, changed, removed или moved (добавление, изменение, удаление или перемещение правил), делает текстовый экспорт конфигурации и отправляет файл на почту.

Чтобы скрипт не отправлял одно и то же письмо по кругу и не реагировал на собственные записи в логе, в коде предусмотрены две защиты: запоминание внутреннего ID последнего обработанного лога ($lastConfigLogID) и фильтр по имени самого скрипта.

Создаем в /system script скрипт с именем email‑config‑on‑change и вставляем следующий код:

:global lastConfigLogID;
:global mtIdentity [/system identity get name];

# Ищем в логах любые действия: добавление, изменение, удаление или перемещение
:local LogGet [:toarray [/log find message~"added|changed|removed|moved"]];
:local LogCount [:len $LogGet];

:if ($LogCount > 0) do={

    :local LogID [:pick $LogGet ($LogCount - 1)];

    # Защита: если этот лог мы уже обработали - выходим
    :if ([:tostr $LogID] = [:tostr $lastConfigLogID]) do={
        :return
    }

    :local output [/log get $LogID message];

    # Исключаем из проверок логи самого скрипта (чтобы не было бесконечного цикла)
    :if ($output ~ "email-config-on-change" or $output ~ "sched-check-config-change") do={
        :return
    }

    :local currentTime [/log get $LogID time];
    :if ([:len $currentTime] = 10) do={
        :set currentTime [:pick $currentTime 0 10];
    }
    
    :local fileName "export_event.rsc"

    # Удаляем старый файл, если он остался
    /file remove [find name=$fileName]

    # Генерируем свежую конфигурацию
    /export compact file=$fileName;
    
    # Даем роутеру 5 секунд, чтобы записать файл на диск
    :delay 5s;

    # Отправляем на вашу почту
    /tool e-mail send to="your-email@domain.com" subject="($mtIdentity) INSTANT export" body="Config modification detected: $output" file=$fileName;

    # Запоминаем ID лога
    :set lastConfigLogID $LogID;
}

(Не забудьте заменить your‑email@domain.com на ваш реальный адрес).

Запуск по расписанию

Чтобы скрипт вовремя отслеживал действия админов, вешаем его в планировщик (/system scheduler) на запуск каждые 30 секунд. Выполняем команду в терминале:

/system scheduler add name=sched-check-config-change interval=30s start-time=startup policy=ftp,read,write,policy,test on-event="/system script run email-config-on-change"

Скрипт работает незаметно: если новых логов об изменении настроек нет, он отрабатывает за сотые доли секунды и никак не нагружает процессор MikroTik. Но как только кто‑то применит изменения в течение этих 30 секунд, актуальный файл конфигурации окажется у вас на почте. Я выбрал интервал в 30 секунд, вы можете поставить другое время, как посчитаете нужным.

Примечание: поскольку поиск идет по общим словам added|changed|removed|moved по всему буферу логов, в некоторых конфигурациях возможны редкие ложные срабатывания. В моей сети это никак не мешает. Во время больших правок конфигурации скрипт лучше временно отключать, чтобы не получать десятки писем подряд и лишний раз не изнашивать флеш‑память роутера.