Еще донедавна мне не удавалось найти в Интернете любительскую метеостанцию с питанием от батареек. Я имею ввиду бытовую автономную метеостанцию с измерениями параметров в помещении, на улице и отображением информации на дисплее метеостанции. Любители не заморачиваются на этой проблеме, а питают свои автономные девайсы от солнечных батарей, аккумуляторов и т.п. Уточню — проблема касается только одного из узлов метеостанции — базы, а первые проекты малогабаритных беспроводных автономных выносных датчиков на Ардуино появились 10 лет назад. Вместе с тем, промышленные устройства такого плана — бытовые метеостанции, комнатные термостаты годами работают от пары батареек АА и этот факт является той целью, которой хотелось бы достичь.
Это было донедавна. Несколько дней назад меня поразил очередной проект @Berkseo, как поражают все его проекты: "Беспроводная мини погодная станция с e-paper экраном на батарейках". Тут все на уровне промышленных бытовых метеостанций, за исключением одного момента — в устройстве нет внешнего датчика.
Полтора года назад разместил статью Автономная метеостанция на контроллере ATMEGA328P и питанием от батареек с беспроводным выносным датчиком. Хотя прототип и выполнял свои функции, но имел серьезные недостатки — слишком малая частота обновления данных и большое энергопотребление.
Ниже — новая версия метеостанции с другими алгоритмами, элементной базой и кодом с низкоуровневыми вставками. Все это позволило выйти на время работы метеостанции от одного комплекта батареек даже несколько больше, чем гарантируют производители некоторых товаров такого плана.
![](https://habrastorage.org/webt/dh/p5/fo/dhp5fow2ni1j5pqv1sk2scx5hym.gif)
Что сделано:
Датчики DHT22 и DS18B20, которые использовались в предыдущем проекте, заменены энергосберегающим модулем — это датчик температуры и влажности HTU21D. Период измерений, отправки/приема данных уменьшен с 15 мин до 53,5 сек. Сделан переход на устойчивую частоту работы контроллера (8 МГц) при напряжении питания ниже 3 В. Для уменьшения объемов занимаемой памяти в скетчах использованы некоторые функции С/С++. И главное, принципиально изменен алгоритм передачи пакетов с выносного датчика и алгоритм приема этих пакетов базой метеостанции. Теперь для обеспечения надежного приема пакетов с выносного датчика в нем формируется и отправляется с интервалом около 0,3 сек не один, а три пакета с данными о параметрах воздуха на улице и состоянии батареек. Только после отправки третьего пакета контроллер в. датчика вместе с периферией уходит в сон. База метеостанции уходит спать после приема одного из 6-ти пакетов с выносного датчика и просыпается за полсекунды до поступления очередной серии пакетов с выносного датчика.
Метеостанция состоит из двух автономных узлов с питанием от двух батареек AA: базы и выносного датчика. Назовем их для простоты анализатором (по-другому – база) и беспроводным в.датчиком (выносным датчиком).
Анализатор, построен на контроллере ATMEGA328P, измеряет температуру и влажность (датчик температуры и влажности HTU21D) в помещении, а также измеряет и анализирует величину напряжения питания узла, которое обеспечивают две батарейки АА 1,5 В. На контроллер также поступает сигнал с приемника LoRa, который по эфиру принимает информацию с выносного датчика. Вся инфа с контроллера выводится на ЖК-дисплей NOKIA 5110.
В в.датчике, тоже собранном на контроллере ATMEGA328P, измеряется температура и влажность воздуха на улице (модуль HTU21D), а также напряжение питания выносного узла, организованного на двух батарейках АА 1,5 В. Передатчик LoRa этого узла передает инфу о температуре, влажности и состоянии батарейки на анализатор. С в.датчика выполняется отправка 3 пакетов с интервалом около 0,3 сек, затем контроллер ATMEGA328P, передатчик LoRa и модуль HTU21D для экономного расходования заряда батареек переводятся в режим сна. Измерения и отправка данных с в.датчика выполняется с циклом несколько меньше 1-ой минуты.
Работа анализатора построена по следующему алгоритму:
Вначале, при включении обоих узлов метеостанции, контроллер анализатора подает команды на измерение температуры и влажности внутри помещения и выводит эти параметры на дисплей, затем устанавливает приемник LoRa в режим прослушивания эфира. После приема сигнала с в.датчика и успешной дешифрации принятых данных контролер подает команду на повторное измерение температуры, влажности и выводит инфу в полном объеме на экран. Затем анализатор уходит в сон, просыпаясь примерно за полсекунды до планируемого поступления сигнала с в.датчика. Приняв и дешифровав один из трех пакетов с в.датчика, повторно выполняет свои измерения, выводит информацию на экран и снова уходит спать. Если по каким-то причинам сигнал с в.датчика отсутствует около одной минуты (например, сели батарейки), что по времени соответствует отправке 6 пакетов с в.датчика, анализатор проводит измерения только в помещении, изредка сканируя эфир: а вдруг в.датчик появился в эфире?! Это сделано для того, чтобы постоянно работающий на прием модуль LoRa не посадил за короткое время батарейки анализатора.
Для сборки устройства понадобятся радиодетали:
- Контроллер ATMEGA328P-PU — 2 шт.
- Датчик влажности и температуры HTU21D/SHT21/Si7021 — 2 шт.
- ЖК-дисплей NOKIA 5110 — 1 шт.
- Приемник-передатчик LoRa Rа-01 — 2 шт.
- Макетная плата (стеклотекстолит), монтажные провода, батарейки АА, кварцевые резонаторы 8 МГц, резисторы, конденсаторы, другие мелочи.
Ориентировочная стоимость компонентов по ценам AliExpress примерно $25.
Для работы с контроллерами ATMEGA328P в качестве программатора я использую плату Arduino UNO. На Youtube есть хорошее видео по установке загрузчика и загрузки скетчей в контроллер ATMEGA328P с помощью платы Arduino UNO.
На этот раз мы не будем устанавливать новые фьюзы программой SinaProg, а воспользуемся, на мой взгляд, более универсальным способом — созданием новых конфигураций плат в платформе Arduino IDE.
В новые контроллеры надо установить загрузчик Arduino as ISP и надо учитывать то, что контроллеры ATMEGA328P поступают в продажу с заводской настройкой фьюз для мониторинга (контроля) напряжения питания не ниже 2,7 В. Мы же будем работать от батареек, напряжение на которых при разряде может быть ниже установленного заводского порога 2,7 В, и с кварцем 8 МГц. Установим загрузчик и изменим фьюзы под наши условия, используя в качестве программатора плату Arduino UNO, в такой последовательности:
- Найти по адресу c:\Program Files\Arduino\hardware\arduino\avr\ файл boards.txt и открыть его текстовом редакторе с форматированием, например, AkelPad.
- Дополнить файл блоком, который приведен под спойлером, и сохранить файл.
блок установок 1##############################################################
amega.name=Mega Low (8 MHz, >1.8V)
amega.upload.tool=avrdude
amega.upload.protocol=arduino
amega.upload.maximum_size=32256
amega.upload.maximum_data_size=2048
amega.upload.speed=57600
amega.bootloader.tool=avrdude
amega.bootloader.low_fuses=0xFF
amega.bootloader.high_fuses=0xDA
amega.bootloader.extended_fuses=0xFE
amega.bootloader.unlock_bits=0x3F
amega.bootloader.lock_bits=0x0F
amega.bootloader.file=optiboot/optiboot_atmega328.hex
amega.build.mcu=atmega328p
amega.build.f_cpu=8000000L
amega.build.board=AVR_UNO
amega.build.core=arduino
amega.build.variant=standard
- В плату Arduino UNO загрузить скетч ArduinoISP.ino из примеров платформы Arduino IDE (Файл –> Примеры –> ArduinoISP).
- Собрать схему (плата Arduino UNO, контроллер ATMEGA328P, кварц 16 МГц) для установки в контроллер загрузчика ArduinoISP (инструкции – тут), подключить ее компьютеру и записать в контроллер бутлоадер Arduino as ISP.
- Заменить кварц в схеме 16 МГц на 8 Мгц. В меню ИНСТРУМЕНТЫ выбрать из списка плату Mega Low (8 MHz, >1.8V), которая появилась в меню после дополнения файла boards.txt новым блоком, выбрать тут же Программатор: “Arduino as ISP” и, нажав Записать загрузчик изменить фьюзы и другие установки в контроллере.
- Далее загружаем в контроллер необходимый скетч, используя ту же схему, что и для установки загрузчика (п.4), через Скетч –> Загрузить через программатор.
Выносной датчик
В.датчик построен на контроллере ATMEGA328P. В нем осуществляется прием данных с HTU21D по протоколу I2C, измерение и анализ величины напряжения питания узла и управление передатчиком LoRa.
/*
Снова о автономной Arduino-метеостанции на батарейках, выносной датчик
https://habr.com/ru/post/544936/
*/
#include <avr/io.h>
#include <util/delay.h>
#include <SPI.h>
#include <LoRa.h>
#include <LowPower.h>
#include <Wire.h>
#include <avr/power.h>
#include "HTU21D.h"
#define VccHTU 8 //питание и подтяжка HTU21D (pin 14 AtMega328P, D8)
HTU21D myHTU21D;
float Tout; // температура
int Hout; // влажность
unsigned int sleepCounter, sleepCounter0; // счетчик, задающий время сна
int pct; //счетчик числа пакетов перед уходом в сон
String messageOut; // LoRa-сообщение
float BatOut; // напряжение батареек
const int batteryPin = A0; // pin 23 (Atmega328P), к которому подключена батарея для измерения напряжения
const float typVbg = 1.132; //калибровочная константа, 1.0 - 1.2
int counter = 0;
// измерение опорного напряжения
float readVcc() {
byte i;
float result = 0.0;
float tmp = 0.0;
for (i = 0; i < 1; i++) {
// Read 1.1V reference against AVcc
// set the reference to Vcc and the measurement to the internal 1.1V reference
#if defined(__AVR_ATmega32U4__) || defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
ADMUX = _BV(REFS0) | _BV(MUX4) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#elif defined (__AVR_ATtiny24__) || defined(__AVR_ATtiny44__) || defined(__AVR_ATtiny84__)
ADMUX = _BV(MUX5) | _BV(MUX0);
#elif defined (__AVR_ATtiny25__) || defined(__AVR_ATtiny45__) || defined(__AVR_ATtiny85__)
ADMUX = _BV(MUX3) | _BV(MUX2);
#else
// works on an Arduino 168 or 328
ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#endif
_delay_ms(3); // Wait for Vref to settle
ADCSRA |= _BV(ADSC); // Start conversion
while (bit_is_set(ADCSRA, ADSC)); // measuring
uint8_t low = ADCL; // must read ADCL first - it then locks ADCH
uint8_t high = ADCH; // unlocks both
tmp = (high << 8) | low;
tmp = (typVbg * 1023.0) / tmp;
result = result + tmp;
_delay_ms(5);
}
return result;
}
void Measurement () {
// измерение температуры и влажности
Hout = myHTU21D.readHumidity();
float Tout_p = myHTU21D.readTemperature();
Tout = 0.1 * int(Tout_p * 10 + 0.5); //округление до десятых
// измерение напряжения батареек
BatOut = 0.1 * int(readVcc() * 10 + 0.5);
if (BatOut < 2.2) {
BatOut = 0.0;
} else {
BatOut = 2.2;
}
}
void SendMessage () {
// отправка данных (температура, влажность, состояние батареек)
if (BatOut > 2.1) {
messageOut = String(Tout) + "#" + String(Hout) + "$" + String("BGood");
}
else {
messageOut = String(Tout) + "#" + String(Hout) + "$" + String("BLow");
}
LoRa.beginPacket();
LoRa.print(messageOut);
LoRa.endPacket();
}
void setup() {
Serial.begin(9600);
Serial.println("Power ON");
analogReference(DEFAULT);
pinMode(VccHTU, OUTPUT);
digitalWrite(VccHTU, 1);
_delay_ms(200);
myHTU21D.begin();
int counter = 0;
while (!LoRa.begin(433E6) && counter < 10) {
Serial.println("Не удалось найти LoRa-передатчик!");
counter++;
_delay_ms(500);
}
LoRa.setTxPower(4); //мощность передатчика, 2...20 дБ
LoRa.setSyncWord(0xF3);
}
void loop() {
digitalWrite(VccHTU, 1);
if (pct < 3)
{ // измерения, отправка пакетов
Serial.println(messageOut);
Measurement ();
SendMessage ();
} else {// измерения, отправка пакета и длительный сон
Serial.println(messageOut);
Serial.println("sleep ...");
Measurement ();
SendMessage ();
for (sleepCounter = 6; sleepCounter > 0; sleepCounter--)
{
digitalWrite(VccHTU, 0);
digitalWrite(VccHTU, 1);
LoRa.sleep ();
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
}
pct = 0;
}
pct++;
if (pct >= 3) pct = 3; //защита от переполнения счетчика
}
int main() {
init();
setup();
for (;;) {
loop();
}
}
Электрическая схема в.датчика:
Питание и подтяжка выводов модуля HTU21D осуществляется с пина 14 контроллера ATMEGA328P. Это сделано для того, чтобы программно обнулить питание HTU21D и перевести этот датчик в режим низкого энергопотребления во время сна.
В в.датчике формируется и отправляется с интервалом около 0,3 сек три пакета с данными о температуре и влажности на улице и состоянии батареек. Если напряжение на батарейках выше установленного порога (2,2 В), то в коде пакета присутствует BGood, а ниже — BLow. После отправки третьего пакета контроллер в.датчика вместе с периферией уходят в сон. Цикл отправки серий пакетов — 53,5 сек.
Анализатор
Мозг анализатора – контроллер ATMEGA328P. Он принимает сигналы с датчика HTU21D по протоколу I2С и по SPI взаимодействует с приемником LoRa и дисплеем NOKIA 5110.
/*
Снова о автономной Arduino-метеостанции на батарейках, анализатор
https://habr.com/ru/post/544936/
*/
#include <avr/io.h>
#include <util/delay.h>
#include <SPI.h>
#include <LoRa.h>
#include <LowPower.h>
#include "HTU21D.h"
#include <LCD5110_Graph.h>
#define VccHTU 8 //питание и подтяжка HTU21D(pin 14 AtMega328P, D8)
HTU21D myHTU21D;
float Tin; // температура в помещении
int Hin; // влажность в помещении
LCD5110 myNokia(3, 4, 5, 6, 7);
extern uint8_t SmallFont[];
extern uint8_t MediumNumbers[];
float BatIn = 0; // напряжение батареи
const int batteryPin = A0; // pin 23(Atmega328P), к которому подключена батарея для измерения напряжения
const float typVbg = 1.132; //калибровочная константа, 1.0 - 1.2
unsigned int sleepCounter; //счетчик, задающий время сна
int r; //счетчик циклов прослушивания эфира
int mlc; //счетчик циклов работы без в.датчика
String LoRaData, Tout_str, Hout_str, BatIn_str, BatOut_str;
// измерение напряжения батареек
float readVcc() {
byte i;
float result = 0.0;
float tmp = 0.0;
for (i = 0; i < 1; i++) {
// Read 1.1V reference against AVcc
// set the reference to Vcc and the measurement to the internal 1.1V reference
#if defined(__AVR_ATmega32U4__) || defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
ADMUX = _BV(REFS0) | _BV(MUX4) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#elif defined (__AVR_ATtiny24__) || defined(__AVR_ATtiny44__) || defined(__AVR_ATtiny84__)
ADMUX = _BV(MUX5) | _BV(MUX0);
#elif defined (__AVR_ATtiny25__) || defined(__AVR_ATtiny45__) || defined(__AVR_ATtiny85__)
ADMUX = _BV(MUX3) | _BV(MUX2);
#else
// works on an Arduino 168 or 328
ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#endif
_delay_ms(3); // Wait for Vref to settle
ADCSRA |= _BV(ADSC); // Start conversion
while (bit_is_set(ADCSRA, ADSC)); // measuring
uint8_t low = ADCL; // must read ADCL first - it then locks ADCH
uint8_t high = ADCH; // unlocks both
tmp = (high << 8) | low;
tmp = (typVbg * 1023.0) / tmp;
result = result + tmp;
_delay_ms(5);
}
return result;
}
void Measurement() {
float Tin0;
// измерение напряжения батареи:
BatIn = readVcc();
// измерение температуры и влажности в помещении
Hin = myHTU21D.readHumidity();
float Tin_p = myHTU21D.readTemperature();
Tin = 0.1 * int(Tin_p * 10 + 0.5); //округление до десятых
}
void draw() {
myNokia.enableSleep();
myNokia.clrScr();
//Tin
char chr_Tin [5];
String Tin_str = String(Tin);
myNokia.setFont(SmallFont);
myNokia.print(" C", LEFT, 0);
myNokia.print("In", LEFT, 8);
myNokia.setFont(MediumNumbers);
Tin_str.toCharArray(chr_Tin, 5); //количество знаков+1
myNokia.print(String(chr_Tin), CENTER, 0);
//Tout
char chr_Tout [5];
myNokia.setFont(SmallFont);
myNokia.print(" C", LEFT, 16);
myNokia.print("Out", LEFT, 24);
myNokia.setFont(MediumNumbers);
Tout_str.toCharArray(chr_Tout, 5);
myNokia.print(String(chr_Tout), CENTER, 16);
// Hin, Hout
char chr_Hout [5];
Hout_str.toCharArray(chr_Hout, 4);
myNokia.setFont(MediumNumbers);
myNokia.print(String(Hout_str), RIGHT, 32);
myNokia.setFont(SmallFont);
myNokia.print(" In Out", LEFT, 40);
myNokia.print(" %", LEFT, 32);
myNokia.setFont(MediumNumbers);
myNokia.print(String(Hin), LEFT, 32);
myNokia.setFont(SmallFont);
// Battery Level
if (BatIn < 2.2) {
myNokia.setFont(SmallFont);
myNokia.print("Bat", LEFT, 0);
}
if (BatOut_str == "BLow") {
myNokia.setFont(SmallFont);
myNokia.print("Bat", LEFT, 16);
}
myNokia.disableSleep();
_delay_ms(5);
}
void drawStart() {
myNokia.enableSleep();
myNokia.clrScr();
//Tin
char chr_Tin [5];
String Tin_str = String(Tin);
myNokia.setFont(SmallFont);
myNokia.print(" C", LEFT, 0);
myNokia.print("In", LEFT, 8);
myNokia.setFont(MediumNumbers);
Tin_str.toCharArray(chr_Tin, 5); //количество знаков+1
myNokia.print(String(chr_Tin), CENTER, 0);
// Battery Level
if (BatIn < 2.2)
{
myNokia.setFont(SmallFont);
myNokia.print("Bat!", RIGHT, 28);
}
//Hin
myNokia.setFont(SmallFont);
myNokia.print(" %", LEFT, 18);
myNokia.print("In", LEFT, 28);
myNokia.setFont(MediumNumbers);
myNokia.print(String(Hin), CENTER, 18);
//No signal!
myNokia.setFont(SmallFont);
myNokia.print("Out - - -", CENTER, 40);
myNokia.update();
myNokia.disableSleep();
_delay_ms(5);
}
void setup() {
Serial.begin(9600);
pinMode(VccHTU, OUTPUT);
digitalWrite(VccHTU, 1);
Serial.println("Power ON!");
analogReference(DEFAULT);
// инициализация дисплея
myNokia.InitLCD();
myNokia.setFont(SmallFont);
myNokia.clrScr();
myNokia.print(">>>>>", CENTER, 20);
myNokia.update();
_delay_ms(1000);
myNokia.setFont(SmallFont);
myNokia.clrScr();
myNokia.print("))-->", CENTER, 20);
myNokia.update();
if (!LoRa.begin(433E6)) {
Serial.println("Ошибка загрузки LoRa-приемника!");
while (1);
myNokia.setFont(SmallFont);
myNokia.clrScr();
myNokia.print(" -> ->", CENTER, 20);
myNokia.update();
}
// Диапазон для синхрослова – между "0-0xFF".
LoRa.setSyncWord(0xF3);
Serial.println("Прослушивание эфира. Ожидание пакета с в.датчика ...");
myHTU21D.begin();
Measurement();
drawStart();
digitalWrite(VccHTU, 0);
_delay_ms(1000);
myNokia.clrScr();
myNokia.print("Waiting", CENTER, 10);
myNokia.print("Message from", CENTER, 22);
myNokia.print("OUTSIDE", CENTER, 34);
myNokia.update();
}
void loop() {
r++;
digitalWrite(VccHTU, 1);
if (r < 600) // 8 MHz;
{
mlc = 0;
// Прослушивание эфира, прием, дешифрация, если сигнал с в.датчика принят,
// то измерения в помещении, вывод инфы на экран и - в спячку.
{
int packetSize = LoRa.parsePacket();
if (packetSize) {
while (LoRa.available()) {
LoRaData = LoRa.readString();
}
int pos1 = LoRaData.indexOf('#');
int pos2 = LoRaData.indexOf('$');
Tout_str = LoRaData.substring(0, pos1);
Hout_str = LoRaData.substring(pos1 + 1, pos2);
BatOut_str = LoRaData.substring(pos2 + 1, LoRaData.length());
if ((LoRaData).substring(pos1, pos1 + 1) == "#") {
Serial.println("Принято, декодировано! r = " + String(r));
r = 0;
Measurement();
draw();
digitalWrite(VccHTU, 0);
// sleepCounter = 49; 16 MHz
// sleepCounter = 48; 8 MHz
for (sleepCounter = 48; sleepCounter > 0; sleepCounter--)
{
digitalWrite(VccHTU, 1);
LoRa.sleep ();
LowPower.powerDown(SLEEP_1S, ADC_OFF, BOD_OFF);
}
}
}
}
} else {
r = 600;
if (mlc < 250) //4 часа, время работы без датчика
{
Serial.println("Работа без в.датчика.");
LoRa.sleep ();
Measurement();
drawStart();
digitalWrite(VccHTU, 0);
for (sleepCounter = 6; sleepCounter > 0; sleepCounter--)
{
digitalWrite(VccHTU, 1);
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
}
mlc++;
} else {
r = 0;
mlc = 0;
}
}
_delay_ms(110);
}
int main() {
init();
setup();
for (;;) {
loop();
}
}
Работа анализатора начинается в setup'e с инициализации модулей, измерения параметров воздуха, анализа напряжения на батарейках и вывода этой инфы на дисплей. Далее уже в loop'e прослушивается эфир приемником LoRa. После приема и дешифрации сигнала с в.датчика повторно проводятся измерения, анализа напряжения на батарейках и вывод измеренной и принятой инфы на дисплей. Выполнив эту работу все элементы схемы уходят поспать примерно на полсекунды меньше, чем период отправки пакетов с в.датчика. В следующем цикле контроллер просыпается и включает приемник приблизительно за 0,5 сек до ожидаемого прихода сигнала с в.датчика. Таким образом, контроллер и периферия анализатора работают с тем же периодом (циклом) что и в.датчик — несколько меньше минуты (53,5 сек), но активны несколько больше времени. Если радиосигнал с в.датчика не поступает на приемник анализатора на протяжении приблизительно одной минуты (это время, достаточное для приема одного из 6 пакетов), то анализатор переходит в режим работы без в.датчика на 4 часа, измеряя параметры воздуха и оценивая состояние батареек только в помещении с индикацией на дисплее этих данных. Период обновления данных в режиме работы без в. датчика — 56,7 сек. В конце четырехчасового цикла работы анализатора без в.датчика он прослушивает эфир: а вдруг в.датчик снова в эфире?
Для перевода модуля HTU21D в режим низкого энергопотребления во время сна его питание также, как и в в.датчике, организовано с контроллера ATMEGA328P (пин 14).
В целом, на дисплее анализатора видна такая картинка:
Дисплей из-за низкого разрешения и малого размера экрана плотно забит символами. Эта картинка смотрелась бы намного лучше на современном дисплее с электронными чернилами. В будущем в своих проектах буду использовать e-paper дисплей.
Ресурс батареек и другое
Для расчета срока работы батареек понадобится время и потребляемый ток во время выполнения работы (операционное время) и сна. Операционное время и рабочий ток измерялись с использованием тестовых скетчей, идея которых взята отсюда. Архив с тестовыми скетчами и данными хронометража лежит здесь.
Рабочий ток измерялся с использованием тех же тестовых скетчей. Для исключения разрывов цепи питания или значительного увеличения величины выходного сопротивления батареек можно использовать шунт 3,9...5,6 Ом и параллельно подключенный к нему цифровой мультиметр с механическим переключением в режиме вольтметра на диапазоне 2000 мкВ. Это критично при измерении потребления тока сна анализатора, поскольку разрыв питания или значительное ограничение тока приводят к циклическому ресету анализатора. Да и выносной датчик может переходить в постоянный рестарт. По мере возможности необходимо проверять ток потребления разными способами на разных диапазонах шкал прибора и с батарейками, которые планируется использовать, притом, обязательно без вывода результатов на монитор порта Ардуино. Невыполнение этих правил сказались на результатах измерений тока в предыдущем моем посте на тему метеостанции — в одних случаях они занижены, в других — завышены.
Результаты измерений сведены в таблицу:
в.датчик | анализатор | |
Операционное время функции измерений параметров воздуха, состояния батареек | 0,25 сек | 0,39 сек |
Операционный ток функции измерений параметров воздуха, состояния батареек | 3,4 мА | 3,5 мА |
Операционное время функции передачи/приема сигнала | 42 мсек | 83 мсек |
Операционный ток функции передачи/приема сигнала | 30,0 мА (4 дБ) |
11,5 мА |
Ток сна | 10 мкА | 190 мкА |
Что бросается в глаза, глядя на эту таблицу. Операционный ток передачи сигнала — 30,0 мА при мощности передатчика LoRa 4 дБ. Для сравнения, заявленный ток передачи для модуля nRF24L01 13,5 мА. Вывод очевиден: надо переходить на nRF24L01.
Средний ток потребления по данным таблицы в. датчика 0,13 мА. Емкости батареек типа АА GP Litium для выносного датчика должно хватить на 2,5 года.
Средний ток потребления анализатора 0,27 мА. Ресурс батареек АА GP Litium в анализаторе — 1,2 года. Для беспроводного комнатного термостата Computherm Q7RF, например, срок действия батареек около 1 года. Неплохо! Конечно, хотелось бы сравнить с базой промышленной метеостанции, но производители этого товара не приводят в комплекте документов ресурса батареек.
Материал, который раньше находился на этом месте, в развернутом виде вынесен сюда: На распутье — Ардуино, Cи или Ассемблер? Заходите!
Не буду скромничать, полученный результат — энергопотребление прототипа на уровне промышленных образцов, меня радует, а совершенству нет предела…
И, наконец, искренне благодарю AlexanderS, который донес до меня идею виртуальной шкалы времени или синхронизации, а также других участников обсуждения статьи «Автономная метеостанция на контроллере ATMEGA328P и питанием от батареек с беспроводным выносным датчиком» за предложения, конструктивную критику и замечания.
Спасибо, кто дочитал. Всем — отличного иммунитета во времена ковида и не только.
Ссылки по теме
Узел беспроводного датчика с низким энергопотреблением
Беспроводная мини погодная станция с e-paper экраном на батарейках
Превращаем Arduino в полноценный AVRISP программатор
Узнайте о битах конфигурации ATmega328P и о том, как использовать их с внешним кварцевым резонатором