Самодельный датчик движения на Zigbee для Home Assistant и Zigbee2MQTT

#include <FastLED.h>
#include "Zigbee.h"

#define LED_PIN     8       // Most ESP32 Mini boards
#define NUM_LEDS    1
#define LED_TYPE    WS2812B
#define COLOR_ORDER GRB



#ifndef ZIGBEE_MODE_ED
#error "Zigbee end device mode is not selected in Tools->Zigbee mode"
#endif

CRGB leds[NUM_LEDS];

/* Zigbee occupancy sensor configuration */
#define OCCUPANCY_SENSOR_ENDPOINT_NUMBER 10
#define TEMP_SENSOR_ENDPOINT_NUMBER 11
uint8_t button = BOOT_PIN;
uint8_t sensor_pin = 10;

ZigbeeOccupancySensor zbOccupancySensor = ZigbeeOccupancySensor(OCCUPANCY_SENSOR_ENDPOINT_NUMBER);
ZigbeeTempSensor zbTempSensor(TEMP_SENSOR_ENDPOINT_NUMBER);

void setup() {
  Serial.begin(115200);
  FastLED.addLeds<LED_TYPE, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS);
  FastLED.setBrightness(50);
  // Init button + PIR sensor
  pinMode(button, INPUT_PULLUP);
  pinMode(sensor_pin, INPUT);

  // Optional: set Zigbee device name and model
  zbOccupancySensor.setManufacturerAndModel("ESP32", "ESP32_Occupancy");
  zbTempSensor.setManufacturerAndModel("ESP32", "ESP32_Occupancy");

  // Add endpoint to Zigbee Core
  Zigbee.addEndpoint(&zbOccupancySensor);
  Zigbee.addEndpoint(&zbTempSensor);

  zbTempSensor.setMinMaxValue(10, 80);
  zbTempSensor.setDefaultValue(25.0);
  zbTempSensor.setTolerance(0.5);   // 0.5°C

  Serial.println("Starting Zigbee...");
  // When all EPs are registered, start Zigbee in End Device mode
  if (!Zigbee.begin()) {
    Serial.println("Zigbee failed to start!");
    Serial.println("Rebooting...");
    ESP.restart();
  } else {
    Serial.println("Zigbee started successfully!");
    leds[0] = CRGB::Green;
    FastLED.show();
  }
  Serial.println("Connecting to network");
  while (!Zigbee.connected()) {
    Serial.print(".");
    delay(100);
  }
  Serial.println();
  zbTempSensor.setReporting(
    10,    // min interval seconds
    300,   // max interval seconds
    0.5    // delta °C (минимальное изменение для репорта)
  );
}

void loop() {
  // Checking PIR sensor for occupancy change
  static bool occupancy = false;
  if (digitalRead(sensor_pin) == HIGH && !occupancy) {
    // Update occupancy sensor value
    zbOccupancySensor.setOccupancy(true);
    zbOccupancySensor.report();
    occupancy = true;
    leds[0] = CRGB::Red;
    FastLED.show();
  } else if (digitalRead(sensor_pin) == LOW && occupancy) {
    zbOccupancySensor.setOccupancy(false);
    zbOccupancySensor.report();
    occupancy = false;
    leds[0] = CRGB::Green;
    FastLED.show();
  }

  static uint32_t lastTempMs = 0;
  if (millis() - lastTempMs > 60000) {
    lastTempMs = millis();
    float t = temperatureRead();              // °C (примерно)
    zbTempSensor.setTemperature(t);           // или setTemperatureValue(...)
    Serial.printf("Chip temp: %.2f C\n", t);
  }

  // Checking button for factory reset
  if (digitalRead(button) == LOW) {  // Push button pressed
    // Key debounce handling
    delay(100);
    int startTime = millis();
    while (digitalRead(button) == LOW) {
      delay(50);
      if ((millis() - startTime) > 3000) {
        // If key pressed for more than 3secs, factory reset Zigbee and reboot
        Serial.println("Resetting Zigbee to factory and rebooting in 1s.");
        delay(1000);
        Zigbee.factoryReset();
      }
    }
  }
  delay(100);
}

const fz = require('zigbee-herdsman-converters/converters/fromZigbee');
const exposes = require('zigbee-herdsman-converters/lib/exposes');
const e = exposes.presets;

module.exports = [{
  fingerprint: [{modelID: 'ESP32_Occupancy', manufacturerName: 'ESP32'}],
  model: 'ESP32_Occupancy',
  vendor: 'ESP32',
  description: 'ESP32 occupancy + chip temperature',
  fromZigbee: [fz.occupancy, fz.temperature],
  toZigbee: [],
  exposes: [
    e.occupancy('occ'),
    e.temperature().withEndpoint('temp'),
  ],
  endpoint: (device) => ({
    occ: 10,
    temp: 11,
  }),
  meta: {multiEndpoint: true},
}];