Автоматизация импорта значений в типовые отчеты «1С: Бухгалтерия предприятия 3.0​»

Привет! Меня зовут Николай, я разработчик 1С в компании SimbirSoft. 

Зачастую при тестировании или анализе данных возникает необходимость сформировать стандартные бухгалтерские отчеты с определенным набором значений, а иногда в отборе требуется сравнить значение реквизита с множеством вариантов. К сожалению, в форме отбора не предусмотрены средства по загрузке значений из внешнего источника. Когда мне потребовалось проанализировать отчет с отбором более 10 000 позиций номенклатуры, я задумался о том, как автоматизировать процесс заполнения отбора. Оказалось, что реализовать это не так сложно. В своей статье я продемонстрирую способ решения этой задачи. 

Кому будет полезно? 

1С-разработчикам и другим 1С-специалистам, сталкивающимся с необходимостью импорта тысяч и десятков тысяч значений вручную.

Например, на создание 100 значений может уйти полчаса, но если требуется загрузить более 10 000, то это может занять дольше времени, и есть риск допустить ошибку, поскольку человеческий фактор никто не отменял.

Если автоматизировать импорт значений, тогда бухгалтеры или другие менеджеры смогут самостоятельно производить загрузку новых значений без привлечения разработчика.

Итак, план действий следующий:

1. Получить форму отчета из списка открытых форм.

2. Сделать загрузку отбора из типового отчета в форму обработки.

3. Загрузить список значений в отбор. Поместить значения в виде текста в добавленный на форму обработки табличный документ, получить из базы соответствующие строковым значениям ссылки из базы данных. Заполнить ими отбор.

4. Загрузить измененный отбор обратно в форму отчета.

Все шаги будут продемонстрированы на примере приложенной к статье обработки.

Тестирование проводилось на конфигурации Бухгалтерия предприятия 3.0.143.32, версия платформы 8.3.22.2239

1. Получить форму отчета из списка открытых форм.

Воспользуемся стандартной функцией языка 1С для получения списка окон ПолучитьОкна. Функция возвращает коллекцию окон открытых в сеансе. Элемент полученной коллекции имеет тип ОкноКлиентскогоПриложения. В интерфейсе это открытая вкладка, содержащая внутри коллекцию форм, к которой можно обратиться через свойство Содержимое типа ОкноКлиентскогоПриложения. Нас интересуют только формы отчетов. Уникальные идентификаторы сохраняем в список значения на форме. Добавляем уникальные идентификаторы с представлением «Имя формы» для удобного представления открытых отчетов:

&НаКлиенте
Процедура ЗагрузитьСписокОкон(СписокОкон)
    
    ОкнаПриложения = ПолучитьОкна();
    
    Для каждого ОкноПриложения Из ОкнаПриложения Цикл
   	 Для каждого Форма Из ОкноПриложения.Содержимое Цикл
   		 Если НЕ ЭтаФорма.УникальныйИдентификатор = Форма.УникальныйИдентификатор Тогда
   			 Если СтрНачинаетсяС(Форма.ИмяФормы, "Отчет.") Тогда
   				 СписокОкон.Добавить(Строка(Форма.УникальныйИдентификатор), ОкноПриложения.Заголовок);
   				 Прервать;
   			 КонецЕсли;
   		 КонецЕсли;
   	 КонецЦикла;
    КонецЦикла;
    
КонецПроцедуры

В список значений Окна загружен список открытых отчетов, в которые мы можем загрузить наши значения в отбор:

Далее предстоит задача передать отбор из выбранного отчета в форму обработки, поэтому переходим к следующему шагу.

2. Сделать загрузку отбора из типового отчета в форму обработки.

Для удобной работы с отбором в реквизиты формы обработки добавлен реквизит с типом КомпоновщикНастроек. Чтобы отразить отбор компоновщика настроек отчета в обработке, инициализируем КомпоновщикНастроек обработки компоновщиком настроек отчета:

В коде ниже функция НайтиОкноПоУникальномуИдентификатору находит по уникальному идентификатору форму выбранного отчета, и если форма еще открыта, передает в процедуру ОкнаПриИзмененииНаСервере компоновщик настроек формы.

	Если ЗначениеЗаполнено(Окна) Тогда
		Форма = НайтиОкноПоУникальномуИдентификатору(Окна);
		Если Форма = Неопределено Тогда
			ПоказатьПредупреждение(,нСтр("ru='Окно не найдено, обновите список окон'", "ru"));
		Иначе
			Если СтрНачинаетсяС(Форма.ИмяФормы, "Отчет.") Тогда
				ОкнаПриИзмененииНаСервере(Форма.Отчет.КомпоновщикНастроек);	
				Возврат;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;

Далее инициализируем компоновщик настроек обработки компоновщиком настроек отчета:

   // КомпоновщикНастроекФормы - компоновщик формы отчета 
	Настройки = КомпоновщикНастроекФормы.ПолучитьНастройки();
	ИсточникДоступныхНастроек = КомпоновщикНастроекФормы.ПолучитьИсточникДоступныхНастроек();
	КомпоновщикНастроек.Инициализировать(ИсточникДоступныхНастроек);
	КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);
	Настройки = КомпоновщикНастроек.ПолучитьНастройки();
	КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);

Компоновщик настроек инициализирован, отбор загружен, пришло время загрузить список значений в отбор. Для этого переходим к шагу 3.

3. Загрузить список значений в отбор.

Когда компоновщик обработки был инициализирован, таблица на форме, связанная с компоновщиком настроек, отразит отборы из отчета. Выберем интересующий отбор из списка отбора на форме отбора. Если выбран ссылочный тип, в список реквизитов будет загружен список реквизитов элемента отбора, выбранного в отборе:

По любому реквизиту из этого списка, можно загрузить значения в отбор. Например, если нужно загрузить список номенклатуры, а у нас есть список кодов номенклатуры, то в этом списке выбираем Код. Также возможен вариант добавления отбора Номенклатура. Код сразу в отбор отчета. Тогда при загрузке и этот элемент отбора попадет в отчет:

Вставим значения, по которым нужно сформировать отчет в табличный документ:

Процедура ЗагрузитьЗначенияИзТабличногоДокумента(Команда)
	ТекущаяСтрока = Элементы.КомпоновщикНастроекНастройкиОтбор.ТекущаяСтрока;
	Если ТекущаяСтрока <> Неопределено Тогда
		ТекущиеДанные = Элементы.КомпоновщикНастроекНастройкиОтбор.ТекущиеДанные;
		ЭлементОтбора = КомпоновщикНастроек.Настройки.Отбор.ПолучитьОбъектПоИдентификатору(ТекущаяСтрока);
		ВидСравненияТекущихДанных = ТекущиеДанные.ВидСравнения;
		ПравоеЗначение = ТекущиеДанные.ПравоеЗначение;
		Если ПравоеЗначение <> Неопределено Тогда
			Если ТипЗнч(ПравоеЗначение) = Тип("СписокЗначений") Тогда
				МассивТипов = ПравоеЗначение.ТипЗначения.Типы();
			Иначе
				МассивТипов = Новый Массив;
				МассивТипов.Добавить(ТипЗнч(ПравоеЗначение));
			КонецЕсли;
			ОписаниеТиповПравогоЗначения = Новый ОписаниеТипов(МассивТипов);
		Иначе
			ОписаниеТиповПравогоЗначения = КомпоновщикНастроек.Настройки.Отбор.ДоступныеПоляОтбора.НайтиПоле(ТекущиеДанные.ЛевоеЗначение).Тип;
		КонецЕсли;
		МассивЗначений = ЗначенияПоРеквизиту(ОписаниеТиповПравогоЗначения, Реквизиты, ОБъект.ТабличныйДокумент);
		Если МассивЗначений.Количество() > 0 Тогда
			ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке;
			ЭлементОтбора.ПравоеЗначение = МассивЗначений;
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Для преобразования строковых значений, загруженных из табличного документа обработки, необходимо определиться с типом значений выбранного отбора. Тут возможны три варианта, в зависимости от того, в каком состоянии отбор отчета перед тем, как был загружен на форму. Если элемент отбора имеет вид сравнения  в списке, то типом значения правого значения отбора будет список значений. Если в отборе стоит вид сравнения, не предполагающий сравнения с коллекцией значения, то возможны еще два варианта. В первом тип определен явно, и он единственный, во втором правое значение не содержит типа. В этом случае в поле правое значение будет значение Неопределено, а тип явно не определен.

В случае со списком значений тип значения можно получить из списка значений через свойство списка значений Список.Значений.ТипЗначений. 

В том случае, когда значение поля ПравоеЗначение равно Неопределено, а тип явно не определен, то тип все же можно определить через свойство отбора компоновщика настроек ДоступныеПоляОтбора.
После определения типа значений можно приступать к извлечению значений из базы данных по загруженным данным из табличного документа.

Если определенный тип оказался простым типом (Строка, Число), то значения просто приводятся к требуемому типу с помощью функции ОписаниеТипа.ПривестиЗначение(), сохраняются в список значений и добавляются в отбор.

Самый интересный случай, когда тип значения приходится определять из доступных полей отбора компоновщика настроек. Так как точный тип значения нам был неизвестен, а через ДоступныеПоляОтбора можно получить объект типа ОписаниеТипов со всеми возможными типами, которые могут быть заданы для данного элемента отбора, пришлось обработать все типы, полученные из ДоступныеПоляОтбора. 

Далее необходимо: 

– обойти каждый тип значения;

– определить доступные реквизиты типа значения, найти среди них тот реквизит, который был выбран для загрузки и найти по нему значения из базы данных. 

– сформировать список значений и загрузить его в отбор.

 Значения для добавления в отбор вставлены, нажмем кнопку:

Код кнопки загрузки значений в отбор:

Функция ЗначенияПоРеквизиту(ОписаниеТиповПравогоЗначения, ИмяРеквизита, ТабличныйДокумент)
	Если ОписаниеТиповПравогоЗначения <> Неопределено Тогда
		СписокЗначенийОтбора = Новый СписокЗначений;
		МассивЗначений = Новый Массив;
		Для Строка=2 По ТабличныйДокумент.ВысотаТаблицы Цикл
			МассивЗначений.Добавить(СокрЛП(ТабличныйДокумент.Область(Строка, 1).Текст));		
		КонецЦикла;	
		Запрос = Новый Запрос;
		ТекстыЗапроса = Новый Массив;		
		Для каждого ТипОтбора Из ОписаниеТиповПравогоЗначения.Типы() Цикл
			Если ЭтоСсылочныйТип(ТипОтбора) Тогда
				ВидОбъекта = ОбщегоНазначения.ВидОбъектаПоТипу(ТипОтбора);
				ОбъектМетаданных = Метаданные.НайтиПоТипу(ТипОтбора);
				ТипОбъекта = ОбъектМетаданных.Имя;			
				РеквизитыОбъектаМетаданных = РеквизитыОбъектаМетаданных(ОбъектМетаданных);
				ИскомыйРеквизитОбъектаМетаданных = Неопределено;
				Для каждого РеквизитОбъектаМетаданных Из РеквизитыОбъектаМетаданных Цикл
					Если РеквизитОбъектаМетаданных.Имя = ИмяРеквизита Тогда
						ИскомыйРеквизитОбъектаМетаданных = РеквизитОбъектаМетаданных;
						Прервать;
					КонецЕсли;
				КонецЦикла;

				ТипыРеквизита = ИскомыйРеквизитОбъектаМетаданных.Тип.Типы();
				Для каждого ТипОтбора Из ТипыРеквизита Цикл
					ЭтоСсылочныйТип = ЭтоСсылочныйТип(ТипОтбора);
					ТекстЗапроса = 
					"ВЫБРАТЬ
					|	%Таблица%.Ссылка КАК %Реквизит%
					|ИЗ
					|	%ВидОбъекта%.%ТипОбъекта% КАК %Таблица%
					|ГДЕ
					|	%ТипОбъекта%.%Реквизит%%.Наименование% В(&МассивЗначений)";
					ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%Таблица%", ТипОбъекта);
					ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%Реквизит%", ИмяРеквизита);
					ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%ВидОбъекта%", ВидОбъекта);
					ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%ТипОбъекта%", ТипОбъекта);
					Если ЭтоСсылочныйТип Тогда
						ВидОбъектаРеквизита = ОбщегоНазначения.ВидОбъектаПоТипу(ТипОтбора);
						ОсновноеПредставление = "Наименование";
						ОбъектМетаданныхТипа = Метаданные.НайтиПоТипу(ТипОтбора);
						Если ОбщегоНазначенияКлиентСервер.ЕстьРеквизитИлиСвойствоОбъекта(ОбъектМетаданныхТипа, "ОсновноеПредставление") Тогда
							ОсновноеПредставление = ОсновноеПредставлениеОбъектаМетаданных(ВидОбъектаРеквизита, ОбъектМетаданныхТипа);
						КонецЕсли;
						ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%.Наименование%", "." + ОсновноеПредставление);
					Иначе
						ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "%.Наименование%", "");
					КонецЕсли;
					ТекстыЗапроса.Добавить(ТекстЗапроса);
				КонецЦикла;
				
			Иначе
				МассивТипов = Новый Массив;
				МассивТипов.Добавить(ТипОтбора);
				ОписаниеТипа = Новый ОписаниеТипов(МассивТипов);
				Для каждого ЗначениеМассива Из МассивЗначений Цикл
					СписокЗначенийОтбора.Добавить(ОписаниеТипа.ПривестиЗначение(ЗначениеМассива));
				КонецЦикла;
			КонецЕсли;
		КонецЦикла;
		Если ТекстыЗапроса.Количество() > 0 Тогда
		Запрос.Текст = СтрСоединить(ТекстыЗапроса, СИМВОЛЫ.ПС + "ОБЪЕДИНИТЬ ВСЕ" + СИМВОЛЫ.ПС);
		Запрос.УстановитьПараметр("МассивЗначений", МассивЗначений);
		РезультатЗапроса = Запрос.Выполнить();
		МассивЗначенийпоТипу = РезультатЗапроса.Выгрузить().ВыгрузитьКолонку(ИмяРеквизита);
		Для каждого ЗначениеМассива Из МассивЗначенийпоТипу Цикл
			СписокЗначенийОтбора.Добавить(ЗначениеМассива);
		КонецЦикла;
		КонецЕсли;
		Возврат СписокЗначенийОтбора;
	КонецЕсли;
	
КонецФункции

Итак, значения преобразованы и загружены в отбор на форме обработки:

Пришло время загрузить отбор обратно в форму отчета. Нажимаем кнопку:

Переходим к четвертому шагу.

4. Загрузить измененный отбор обратно в форму отчета.

	НастройкиКомпоновщикаНастроекФормы = Форма.Отчет.КомпоновщикНастроек.Настройки;
	ЭлементыОтбораФормы = НастройкиКомпоновщикаНастроекФормы.Отбор.Элементы;
	Форма.Элементы.РазделыОтчета.ТекущаяСтраница = Форма.Элементы.НастройкиОтчета;
	ЭлементыОтбораКомпоновщикаНастроек =  КомпоновщикНастроек.Настройки.Отбор.Элементы;
	Для каждого ЭлементОтбора Из ЭлементыОтбораКомпоновщикаНастроек Цикл
		Если ЭлементОтбора.Использование Тогда
			ИндексЭлемента = ЭлементыОтбораКомпоновщикаНастроек.Индекс(ЭлементОтбора);
			ЗаполнитьЗначенияСвойств(ЭлементыОтбораФормы[ИндексЭлемента], ЭлементОтбора);
		КонецЕсли;
	КонецЦикла;
	Форма.Отчет.КомпоновщикНастроек.ЗагрузитьНастройки(НастройкиКомпоновщикаНастроекФормы);
	Форма.Активизировать();

Отбор загружается на форму отчета, далее активизируем форму отчета с загруженным отбором:

По кнопке «Сформировать» формируем отчет с загруженным отбором.

Что у нас получилось в итоге, можно посмотреть здесь.

Заключение

В статье мы с вами рассмотрели способ загрузки в отчет отбора из внешнего источника, который довольно трудоемко добавлять вручную. 

Думаю, что задачи подобного рода возникают достаточно часто, даже если не приходится добавлять тысячи значений. Но и добавление пятидесяти – это уже большая потеря времени, а когда приходится добавлять отбор снова и снова, то сроки увеличиваются в несколько раз.

Описанный подход в статье подходит не только для того, что значительно сократить затрачиваемое время разработчиков. Результат такой доработки позволяет клиентам без участия разработчиков самостоятельно производить загрузки большого количества данных через электронные таблицы.

Надеюсь, статья поможет сэкономить время в следующий раз, когда появится необходимость в заполнении отбора отчета в конфигурации Бухгалтерия предприятия 3.0.​

Спасибо за внимание! Больше авторских материалов для 1С-разработчиков от моих коллег читайте в соцсетях SimbirSoft – ВКонтакте и Telegram.

Рекомендуем другие наши статьи по 1С: 

Система 1С:ERP: наводим «цифровой порядок» на складе

1C-проекты и тестирование: взгляд QA-специалистов

Интеграция с 1С: то, о чем не рассказывают в книгах  

Три консоли в инструментах разработчика 1С: упрощаем отладку кода, запросов и отчетов