Objective-c блоки и c++ лямбды

int multiplier = 7;
int (^myBlock)(int) = ^(int num) { return num * multiplier;};
NSLog(@”%d”, myBlock(4)); // выведет 28

• ^ — этот символ говорит компилятору о том что переменая — блок
• int — блок принимает один параметр типа int, и возвращает параметр типа int
• multiplier — переменная которая приходит к нам из контекста (об этом более подробно в разделе “Захват контекста”)

// имплементация категории
@implementation NSArray (Blocks)
// метод возвращает массив, элементы которого соответствуют предикату
- (NSArray*)subarrayWithPredicate:(BOOL(^)(id object, NSUInteger idx, BOOL *stop))predicte {
    NSMutableArray *resultArray = [NSMutableArray array];
    BOOL shouldStop = NO;
    for (id object in self) {
        if (predicte(object, [self indexOfObjectIdenticalTo:object], &shouldStop)) {
            [resultArray addObject:object];
        }
        if (shouldStop) {
            break;
        }
    }
    return [[resultArray copy] autorelease];
}
@end

// где-то в клиентском коде
    NSArray *numbers = @[@(5), @(3), @(8), @(9), @(2)];
    NSUInteger divisor = 3;
    NSArray *divisibleArray = [numbers subarrayWithPredicate:^BOOL(id object, NSUInteger idx, BOOL *stop) {
        BOOL shouldAdd = NO;
        // нам нужны числа кратные 3
        NSAssert([object isKindOfClass:[NSNumber class]], @"object != number");
        // обратим внимание, что переменную divisor мы взяли из контекста
        if ([(NSNumber *)object intValue] % divisor == 0) {
            shouldAdd = YES;
        }
        return shouldAdd;
    }];
    NSLog(@"%@", divisibleArray); // выведет 3, 9

typedef int (^MyBlockType)(int number, id object);

int multiplier = 7;
auto lambda = [&multiplier](int num) throw() -> int
{
     return multiplier * num;
};
lambda(4); // равно 28

• [] — начало объявления лямбды, внутри — захват контекста
• &multiplier — захваченная переменная (& означает что захвачена по ссылке)
• int — входной параметр
• mutable — ключевое слово которое позволяет модифицировать переменные захваченные по значению
• throw() — обозначает что лямбда не выбрасывает никаких исключений наружу

template<class InputCollection, class UnaryPredicate>
void subset(InputCollection& inputCollection, InputCollection& outputCollection, UnaryPredicate predicate)
{
    typename InputCollection::iterator iterator = inputCollection.begin();
    for (;iterator != inputCollection.end(); ++iterator) {
        if (predicate(*iterator)) {
            outputCollection.push_back(*iterator);
        }
    }
    return;
}

int main(int argc, const char * argv[])
{
        int divisor = 3;
        std::vector<int> inputVector = {5, 3, 8, 9, 2};
        std::vector<int> outputVector;
        subset(inputVector, outputVector, [divisor](int number){return number % divisor == 0;});
        // выводим значения полученной коллекции
        std::for_each( outputVector.begin(), 
                       outputVector.end(), 
                       [](const int& number){std::cout << number << std::endl;} );
}

__block int first = 7;
void (^myBlock2)(int) = ^(int second) { first += second;};
myBlock2(4);
NSLog(@"%d", first); // выведет 11

NSMutableArray *array = [NSMutableArray array];
void (^myBlock3)() = ^() { [array addObject:@"someString"];};
myBlock3(); // добавит someString в array

typedef void (^PKHTTPRequestCompletionSuccessBlock)(NSString *responseString);
typedef void (^PKHTTPRequestCompletionFailBlock)(NSError* error);

@protocol PKRequest <NSObject>

- (void)startRequest;

@end

@interface PKHTTPRequest : NSObject <PKRequest>

// designated initializer
- (id)initWithURL:(NSURL *)url
     successBlock:(PKHTTPRequestCompletionSuccessBlock)success
        failBlock:(PKHTTPRequestCompletionFailBlock)fail;

@end

@interface PKHTTPRequest () <NSURLConnectionDelegate>

@property (nonatomic, copy) PKHTTPRequestCompletionSuccessBlock succesBlock;
@property (nonatomic, copy) PKHTTPRequestCompletionFailBlock failBlock;
@property (nonatomic, retain) NSURL *url;
@property (nonatomic, retain) NSURLConnection *connection;
@property (nonatomic, retain) NSMutableData *data;

@end

@implementation PKHTTPRequest

#pragma mark - initialization / deallocation

// designated initializer
- (id)initWithURL:(NSURL *)url
     successBlock:(PKHTTPRequestCompletionSuccessBlock)success
        failBlock:(PKHTTPRequestCompletionFailBlock)fail {
    self = [super init];
    if (self != nil) {
        self.succesBlock = success;
        self.failBlock = fail;
        self.url = url;
        NSURLRequest *request = [NSURLRequest requestWithURL:self.url];
        self.connection = [[[NSURLConnection alloc] initWithRequest:request
                                                           delegate:self
                                                   startImmediately:NO] autorelease];
    }
    return self;
}

- (id)init {
    NSAssert(NO, @"Use desiganted initializer");
    return nil;
}

- (void)dealloc {
    self.succesBlock = nil;
    self.failBlock = nil;
    self.url = nil;
    self.connection = nil;
    self.data = nil;
    [super dealloc];
}

#pragma mark - public methods

- (void)startRequest {
    self.data = [NSMutableData data];
    [self.connection start];
}

#pragma mark - NSURLConnectionDelegate implementation

- (void)connection:(NSURLConnection *)connection didReceiveData:(NSData *)data {
    [self.data appendData:data];
}

- (void)connection:(NSURLConnection *)connection didFailWithError:(NSError *)error {
    self.failBlock(error);
    self.data = nil;
}

- (void)connectionDidFinishLoading:(NSURLConnection *)connection {
    self.succesBlock([NSString stringWithUTF8String:self.data.bytes]);
    self.data = nil;
}

@end

typedef void (^PKGetUserNameRequestCompletionSuccessBlock)(NSString *userName);
typedef void (^PKGetUserNameRequestCompletionFailBlock)(NSError* error);

@interface PKGetUserNameRequest : NSObject <PKRequest>

- (id)initWithUserID:(NSString *)userID
        successBlock:(PKGetUserNameRequestCompletionSuccessBlock)success
           failBlock:(PKGetUserNameRequestCompletionFailBlock)fail;

@end

NSString *kApiHost = @"http://someApiHost.com";
NSString *kUserNameApiKey = @"username";

@interface PKGetUserNameRequest ()

@property (nonatomic, retain) PKHTTPRequest *httpRequest;

- (NSString *)parseResponse:(NSString *)response;

@end

@implementation PKGetUserNameRequest

#pragma mark - initialization / deallocation

- (id)initWithUserID:(NSString *)userID
        successBlock:(PKGetUserNameRequestCompletionSuccessBlock)success
           failBlock:(PKGetUserNameRequestCompletionFailBlock)fail {
    self = [super init];
    if (self != nil) {
        NSString *requestString = [kApiHost stringByAppendingFormat:@"?%@=%@", kUserNameApiKey, userID];
        self.httpRequest = [[[PKHTTPRequest alloc] initWithURL:[NSURL URLWithString:requestString]
                                                  successBlock:^(NSString *responseString) {
                                                      // роковая ошибка - обращение к self
                                                      NSString *userName = [self parseResponse:responseString];
                                                      success(userName);
                                                  } failBlock:^(NSError *error) {
                                                      fail(error);
                                                  } ] autorelease];
    }
    return self;
}

- (id)init {
    NSAssert(NO, @"Use desiganted initializer");
    return nil;
}

- (void)dealloc {
    self.httpRequest = nil;
    [super dealloc];
}

#pragma mark - public methods

- (void)startRequest {
    [self.httpRequest startRequest];
}

#pragma mark - private methods

- (NSString *)parseResponse:(NSString *)response {
    /* ...... */
    return userName;
}

@end

// разрываем цикл владения
__block PKGetUserNameRequest *selfRequest = self;
self.httpRequest = [[[PKHTTPRequest alloc] initWithURL:[NSURL URLWithString:requestString]
                                          successBlock:^(NSString *responseString) {
                                              NSString *userName = [selfRequest parseResponse:responseString];
                                              success(userName);
                                          } failBlock:^(NSError *error) {
                                              fail(error);
                                          } ] autorelease];

void addBlockToArray(NSMutableArray* array) {
    NSString *string = @"example string";
    [array addObject:^{
        printf("%@\n", string);
    }]; 
}

void example() {
     NSMutableArray *array = [NSMutableArray array];
    addBlockToArray(array);
    void (^block)() = [array objectAtIndex:0];
    block();
}

// Способ №1
auto lamb = []() {return 5;};
auto func_lamb_ptr = new std::function<int()>(lamb);

// Способ №2:
auto lamb = []() {return 5;};
auto* p = new decltype(lamb)(lamb);

// Способ №3:
template <typename T>
T* heap_alloc(T const& value)
{
    return new T(value);
}

auto* p = heap_alloc([]() {return 5;});

// Способ №4:
std::vector<decltype(lamb)> v;
v.push_back(lamb);