AndreyMI May 24 2013 at 02:07

Смешивание текстур ландшафта

3 min

91K

Game development*Algorithms*

Tutorial

+231

Comments 27

agasper May 24 2013 at 02:23

Исходника шейдера не будет?

AndreyMI May 24 2013 at 09:34

Оригинальный шейдер является частью коммерческого проекта, поэтому его исходников не будет.
Но если вы хотите повторить эксперимент в Unity 3D, то создайте сцену с плоскостью и назначьте ей следующий шейдер:

Код шейдера из статьи

Shader "Custom/Demo" {
	Properties {
		_Tex1 ("Texture 1 (RGB) Depth (A)", 2D) = "white" {}
		_Tex2 ("Texture 2 (RGB) Depth (A)", 2D) = "white" {}
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		#pragma surface surf Lambert

		sampler2D _Tex1;
		sampler2D _Tex2;

		struct Input {
			float2 uv_Tex1;
			float2 uv_Tex2;
		};

		float3 blend(float4 texture1, float a1, float4 texture2, float a2)
		{
			float depth = 0.2;
			float ma = max(texture1.a + a1, texture2.a + a2) - depth;
			float b1 = max(texture1.a + a1 - ma, 0);
			float b2 = max(texture2.a + a2 - ma, 0);
			return (texture1.rgb * b1 + texture2.rgb * b2) / (b1 + b2);
		}

		void surf (Input IN, inout SurfaceOutput o) {
			half4 c1 = tex2D (_Tex1, IN.uv_Tex1);
			half4 c2 = tex2D (_Tex2, IN.uv_Tex2);
			o.Albedo = blend(c1, IN.uv_Tex2.x, c2, 1 - IN.uv_Tex2.x);
		}
		ENDCG
	} 
	FallBack "Diffuse"
}

AndreyMI Sep 13 2013 at 11:18

Нашу реализацию данного алгоритма можно найти на Unity3D Asset Store

PavloG May 24 2013 at 02:45

Как это разширяется на >2 леера?
Филлрейт явно сильно выше (особенно если надо еще и нормалмапы смешивать)

Но решение интересное

mayorovp May 24 2013 at 07:56

Как это разширяется на >2 леера?

Последовательно расширяется. Смешали 2 компоненты — результат смешиваем с третьей. Поскольку максимум — ассоциативная и коммутативная функция, порядок не важен.

AndreyMI May 24 2013 at 10:05

Очень просто. Добавьте еще один слой в графики:)
Или, как уже заметил mayorovp, последовательное расширение.

В шейдере для своей игрушки я смешиваю 4 разных текстуры вместе с картами нормалей и одну карту шума.
После игр с математическими операциями мне даже удалось уложиться в ограничения SM2.0.

PavloG May 24 2013 at 12:09

Тоесть для 3ех лееров это будет выглядеть вот так?

float3 blend(float4 texture1, float a1, float4 texture2, float a2,float4 texture3, float a3)
{
    float depth = 0.2;
    float ma = max(max(texture1.a + a1, texture2.a + a2),texture3.a + a3) - depth;

    float b1 = max(texture1.a + a1 - ma, 0);
    float b2 = max(texture2.a + a2 - ma, 0);
    float b3 = max(texture3.a + a3 - ma, 0);

    return (texture1.rgb * b1 + texture2.rgb * b2+texture3.rgb * b3) / (b1 + b2+b3);
}

AndreyMI May 24 2013 at 12:24

Совершенно верно

Bagobor May 25 2013 at 13:27

Филрейт будет больше относительно какого метода?

linqu May 24 2013 at 08:41


float3 blend(float4 texture1, float a1, float4 texture2, float a2)
{
    return texture1.a > texture2.a ? texture1.rgb : texture2.rgb;
}

texture1.a и texture2.a — это что за переменная? откуда берется?

Triang3l May 24 2013 at 09:04

texture1 и texture2 — это цвета пикселя на текстуре. В коде вызовы texture2D убраны.

Triang3l May 24 2013 at 09:02

Красиво, но ?: в шейдере? Как так можно?

// второй шейдер
mix(texture1.rgb, texture2.rgb, step(texture1.a, texture2.a));
// третий шейдер
mix(texture1.rgb, texture2.rgb, step(texture1.a + a1, texture2.a + a2));

AndreyMI May 24 2013 at 10:17

В основном для наглядности, в конечном шейдере нет условных переходов.

Не вижу mix в Cg, наверно lerp?

Triang3l May 24 2013 at 15:24

Да, lerp. Я на GLSL написал.

Darthman May 24 2013 at 10:11

Увидев картинку в шапке, рассчитывал на статью побольше.

Допустим нам надо сделать такой методикой островок камушков посреди песка. Как с этим справиться, используя Ваш алгоритм?
То, что Вы показали очень частный случай и в нем-то всё хорошо, красиво и просто. Мой вопрос связан, по сути, с непосредственным использованием Вашего алгоритма на практике. Давайте для простоты решим что мы делаем стратегию в 2д.

AndreyMI May 24 2013 at 10:46

Шейдер как раз и разрабатывался для изометрической 2D стратегии.
С островками никаких проблем нет, мы просто рисуем их на карте прозрачности слоев.

Карта прозрачности

Darthman May 24 2013 at 10:48

Тоесть карту прозрачности готовите заранее, или на лету делаете?

AndreyMI May 24 2013 at 10:56

Карта прозрачности готовится прямо в Unity в самописном редакторе.
Но она легко может меняться даже непосредственно в игре.

Darthman May 24 2013 at 13:46

Может быть тогда стоит написать в начале статьи, что код и реализация на Unity?

Мне вот, как разработчику под собственный фреймворк, и пишущем на hlsl этот код шейдера немного непривычен :)
В начале я даже было подумал что это псевдокод шейдера.

AndreyMI May 26 2013 at 23:23

Я старался сделать упор именно на алгоритме, а не на конкретной реализации.

Triang3l May 27 2013 at 12:21

Это не целые шейдеры же, а только одна функция. А Cg и HLSL практическип одинаковы.
А если заменить float3 на vec3 и float4 на vec4 (или написать #define float3 vec3 и #define float4 vec4), получится GLSL.

GraD_Kh May 24 2013 at 10:30

Я никогда графикой не занимался, поэтому прошу прощения, если вопрос тривиальный.
Откуда Вы получили карту высот? Сгенерировали автоматически из текстур? Сделали руками «на глаз»? Или она была получена при генерировании текстуры?